Define Class gridDinamic As Grid
	Visible = .T.
	DeleteMark = .F.
	RecordMark = .F.
	HighlightStyle = 2
	SplitBar = .F.
Enddefine


Define Class pornesteLans As Session

	Procedure text1DblClick
		This.lans(crsSets_categorii.id_set)
	Endproc

	Procedure text1KeyPress
		Parameters nKeyCode, nShiftAltCtrl
		If nKeyCode = 13
			This.lans(crsSets_categorii.id_set)
		Endif
	Endproc

	Procedure lans
		Parameters tnId_set
		Set DataSession To 1
		Private pl_verificat
		pl_verificat = .F.
		Private _program
		_program = 'cont'
		Local lcSql, lnSucces, lnLinii, lnLiniiReq

		lcSql = [select r.valoare_default,r.id_item,i.camp_lista, i.id_fisier,pack_util.GetText(i.fis_lista,] + ;
			[i.id_fisier, to_number(r.valoare_default), replace(i.camp_lista,  ','  ,  ' || '' '' || ')) ] + ;
			[as valoare_default_text, i.var_item ] + ;
			[from xrequest r ] + ;
			[join xitems i on i.id_item = r.id_item ] + ;
			[where r.id_set = ?tnId_set and r.valoare_default is not null ]

		lnSucces = goExecutor.oExecute(lcSql, [crsRequest])
		If lnSucces < 0
			Messagebox([Eroare])
			Return
		Endif
		lnLiniiReq = Reccount("crsRequest") * 2
		If lnLiniiReq = 0
			Messagebox([Nu exista note predefinite pentru aceasta categorie])
			Return
		Endif
		lcSql = [select n.cont,n.id_part,n.id_set, p.nume, n.tip  ] + ;
			[  from (select n1.xscd as cont, n1.id_partd as id_part, n1.id_set, 'D' as tip ] + ;
			[          from xnote n1 ] + ;
			[         where nvl(n1.id_partd, 0) <> 0 and n1.id_set = ?tnId_Set  ] + ;
			[        union ] + ;
			[        select n2.xscc as cont, n2.id_partc as id_part, n2.id_set, 'C' as tip ] + ;
			[          from xnote n2 ] + ;
			[         where nvl(n2.id_partc, 0) <> 0 and n2.id_set = ?tnId_Set  ) n ] + ;
			[  join nom_parteneri p on n.id_part = p.id_part]
		lnSucces = goExecutor.oExecute(lcSql,[crsNumePartener])
		If lnSucces<0
			amessagebox(goExecutor.ceroare,0+16,[Eroare])
			Return
		Endif
		lnLinii = Reccount("crsNumePartener") * 2

		Dimension laValori(lnLiniiReq + lnLinii,4)

		Select crsRequest
		i = 1

		Scan
			laValori(i,1) = "poAct." + Allt(Nvl(crsRequest.id_fisier,[]))
			laValori(i,2) = Allt(Nvl(crsRequest.valoare_default,[]))
			laValori(i,3) = .F.
			laValori(i,4) = .T.

			laValori(i+1,1) = "poAct." + Allt(Nvl(crsRequest.var_item,[]))
			laValori(i+1,2) = Alltrim(Nvl(crsRequest.valoare_default_text,[]))
			laValori(i+1,3) = .F.
			laValori(i+1,4) = .T.
			i = i + 2
		Endscan

		Select crsNumePartener
		Scan
			laValori(i,1) = "poact.id_vv" + Alltrim(Nvl(crsNumePartener.Cont,[])) + ;
				IIF(INLIST(LEFT(cont,2),'51','53'),IIF(tip = 'D' ,'0','1'),'')
			laValori(i,2) = Alltrim(Str(Nvl(crsNumePartener.id_part,0)))
			laValori(i,3) = !Empty(Nvl(crsNumePartener.id_part,0))
			laValori(i,4) = .T.

			laValori(i+1,1) = "poact.v" + Alltrim(crsNumePartener.Cont)+ ;
				IIF(INLIST(LEFT(cont,2),'51','53'),IIF(tip = 'D' ,'0','1'),'')
			laValori(i+1,2) = Alltrim(Nvl(crsNumePartener.nume,[]))
			laValori(i+1,3) = !Empty(Nvl(crsNumePartener.id_part,0))
			laValori(i+1,4) = .T.
			i = i + 2
		Endscan

		Select xsets
		If Seek(tnId_set,"xsets")
			Scatter Name loxset
			If loxset.aleg_cont
				Private pcACN, cn, cn2, pcACN2
				Store '' To pcACN, cn, cn2, pcACN2
			Endif
		Endif

		lans(tnId_set,.T.,.T.,@laValori)
		Use In (Select("crsNumePart"))
		Use In (Select("crsRequest"))
	Endproc
Enddefine

***********************************	incaseaza_monetar_50505 ***************************
Procedure incaseaza_monetar_50505

	Private pl_verificat
	pl_verificat = .F.

	Local lnRaspuns, loIm
	Private pcCont1, pcAcont1, pcCont2, pcAcont2
	Private pcACN, cn, cn2, pcACN2, loCont, loCont2, _program
	_program = 'cont'
	lnRaspuns = 6
	Do While lnRaspuns = 6
		Store '' To pcACN, cn, cn2, pcACN2
		loCont = ret_cont("Selectati contul",'704,707')
		If gnButon = 2
			lnRaspuns = 7
		Else
			pcCont1=loCont.Cont
			pcAcont1=loCont.Acont

			loCont2=ret_cont("Selectati contul",'4111')
			If gnButon = 2
				lnRaspuns = 7
			Else
				pcCont2=loCont2.Cont
				pcAcont2=loCont2.Acont

				Do update_jtva_coloane With [JV]

				Create Cursor crsIncasare_monetar (serie c(15),id_part N(10),nr_factura N(14), ;
					nr_incasare N(14), numeclient c(60), valctva N(17,gnPa), valftva N(17,gnPa), ;
					valtva N(17,gnPa), id_jtva_coloana i(4),cota_tva N(2))
				Select crsIncasare_monetar

				loIm = Createobject('frm_incasare_monetar_50505')
				loIm.Show(1)
				If Used('crsIncasare_monetar')
					Use In crsIncasare_monetar
				Endif

				If Used('actactan_o')
					Use In actactan_o
				Endif
			Endif
		Endif

		If lnRaspuns <> 7
			lnRaspuns =	amessagebox('Doriti sa continuati cu operatii de acest fel?',4+32,"Confirmare")
		Endif
	Enddo
*	Release lnRaspuns,pcCont1,pcAcont1,pcCont2,pcAcont2

Endproc		&&	incaseaza_monetar_50505 ***************************

*************	incaseaza_monetar	*********************************
Procedure incaseaza_monetar
	Local loIm,	lnRaspuns
	Private pl_verificat
	pl_verificat = .F.
	Private pcCont1, pcAcont1, pcCont2, pcAcont2
	Private pcACN, cn, cn2, pcACN2, loCont, loCont2, _program

	lnRaspuns = 6
	Do While lnRaspuns = 6

		Do update_jtva_coloane With [JV]

		Create Cursor crsIncasare_monetar (serie c(15),id_part N(10),nr_factura N(14), ;
			nr_incasare N(14), numeclient c(60), valctva N(17,gnPa), valftva N(17,gnPa), ;
			valtva N(17,gnPa), id_jtva_coloana i(4),cota_tva N(2))
		Select crsIncasare_monetar

		loIm = Createobject('frm_incasare_monetar')
		loIm.Show(1)
		If Used('crsIncasare_monetar')
			Use In crsIncasare_monetar
		Endif
		If lnRaspuns <> 7
			lnRaspuns =	amessagebox('Doriti sa continuati cu operatii de acest fel?',4+32,"Confirmare")
		Endif
	Enddo

Endproc		&&	incaseaza_monetar ^^	*********************************